Evaluating TVS Protection Circuits with SPICE

Jan 1, 2006 12:00 PM
By Jim Lepkowski, Senior Applications Engineer, ON Semiconductor, Phoenix, and William Lepkowski, Un

A transient-voltage-suppression diode macromodel offers greater accuracy than a standard diode SPICE model.

SPICE circuit simulations are a powerful design tool to analyze a system's immunity against conducted EMI surge voltages. SPICE can serve as a valuable tool to validate and optimize the performance of surge-protection circuits using transient-voltage-suppression (TVS) avalanche diodes. The small size, fast response time, low clamping voltage and low cost of TVS diodes provides for an effective solution to solve surge problems. A comparison of SPICE simulations with bench tests demonstrates the ability of TVS avalanche diodes to clamp the surge voltages caused by noise sources such as inductive devices and load switching.

I Versus V Characteristics

Zener and TVS avalanche diodes have similar electrical characteristics; however, there are significant differences between the two devices. A zener is designed to regulate a steady-state voltage, while a TVS diode is designed to clamp a transient-surge voltage. In addition, TVS diodes typically have a larger junction area than a standard zener, which provides the ability to absorb high peak energy. The current versus voltage relationship of a TVS diode is shown in Fig. 1.

The graph in Fig. 1 depicts various diode parameters. I_F is the forward current and V_F is the associated forward voltage at that current. I_R is the reverse leakage current and V_RWM is the reverse-working voltage at I_R. Typically, V_{RWM (typ.)} ≅ 0.8 × V_BR. Other parameters include I_T, the test current; V_BR, the breakdown voltage at I_T; and I_PP, the maximum reverse peak pulse current. I_PP is typically specified with either the 8 × 20-µs or 10 × 1000-µs surge pulse. In addition, V_C is the clamping voltage at I _PP.

TVS Diode SPICE Models

The majority of the TVS avalanche diode SPICE models available are created with the SPICE “D” diode statement. There are several restrictions that limit the accuracy of using the diode “D” statement to model a TVS avalanche diode.

First, the diode statement does not have a provision for defining a separate series resistance for the forward- and reverse-bias breakdown regions. The resistances in the two regions are not equal; thus, it is not possible to accurately model the slope of the current versus voltage characteristic in both regions. Next, the “D” statement does not have a variable to model the variance of the breakdown voltage with temperature. Table 1 provides the variables available with the PSPICE “D” diode model.

Macro-Model Subcircuit

A TVS diode macro-model offers several advantages over the standard diode model available in SPICE, including a more accurate representation of the breakdown characteristic. TVS macro-models are created by combining standard SPICE devices into a subcircuit. Fig. 2 shows a schematic for a macro-model of a TVS avalanche diode. A PSPICE netlist for this model appears below. This particular netlist models the NUP2105, a dual, bidirectional voltage suppressor from Phoenix-based ON Semiconductor (Fig. 3).

**************************************************************************************************************

*NUP2105 PSPICE macro-model

*Bidirectional TVS avalanche diode, SOT-23, V_BR = 26.4 V

*Model simulates 1 of the 2 bidirectional TVS devices

******************************************************

*D_{A Cathode} = 1, D_{B Cathode} = 2, D_{A,B Common Anode} = 3

.SUBCKT NUP2105 1 2 3

*Bidirectional devices are formed from two unidirectional

*devices

X1 3 1 HALFNUP2105

X2 3 2 HALFNUP2105

.ENDS NUP2105

******************************************************

*Model HALFNUP2105 represents one bidirectional pair

*of a dual device

*Anode = 7, Cathode = 1

.SUBCKT HALFNUP2105 7 1

*Forward Region

*D1's CJO term models the capacitance

D1 2 1 MDD1

.MODEL MDD1 D IS=1.83708e-14 N=1 XTI=1 RS=0.2

+ CJO=26.4e-12 TT=1e-08

******************************************************

*Leakage Region

*RL models leakage current (I_L)

*MDR temp. coef. model ΔI_L / ΔT

RL 1 2 MDR 4.32244e+08

.MODEL MDR RES TC1=0 TC2=0

******************************************************

*Reverse Breakdown Region

*RZ models the ΔI / ΔV slope

RZ 2 3 1.28

D2 4 3 MDD2

.MODEL MDD2 D IS=2.5e-15 N=0.5

*Breakdown Voltage (V_BR) = IBV × RBV

EV1 1 4 6 8 1

IBV 0 6 0.001

RBV 6 0 MDRBV 26357.1

*MDRBV temp. coef. model ΔV_BR/ΔT

.MODEL MDRBV RES TC1=0.00096

D3 8 0 MDD2

IT 0 8 0.001

***************************************

*L models the lead-to-silicon connection

*package inductance

*L is distributed between two diodes for

*bidirectional diodes

L 7 2 1.24e-9

*

.ENDS HALFNUP2105

**************************************************************************************************************

The TVS macro-model is based on the zener diode model provided in references 3 and 4. References 1 and 2 provide additional information on modeling TVS devices.

Acceptable Use Policy blog comments powered by Disqus